How to move all open tabs from Safari to Firefox?

Question

In my case I have many tabs opened in Safari and I want to move to Firefox. I know I can note down all the url in a text file and open all of them again one by one in another browser. But I'm looking for any shortcut way.

Create bookmarks for the open tabs, export the bookmarks, then import the exported bookmarks. — Ramhound, Sep 30 '14 at 13:20
possible duplicate of [Is there a method to export the URLs of the open tabs of a Firefox window?](http://superuser.com/questions/96739/is-there-a-method-to-export-the-urls-of-the-open-tabs-of-a-firefox-window) — Raystafarian, Sep 30 '14 at 16:37

score 6 · Answer 1 · answered May 19 '17 at 10:44

You could use the following AppleScript:

tell application "Firefox"
    activate
    set newTabURLs to takeSafariTabURLs() of me
    repeat with tabURL in newTabURLs
        open location tabURL
        delay 1
    end repeat

end tell

on takeSafariTabURLs()
    set tabURLs to {}
    tell application "Safari"
        repeat with w in windows
            if name of w is not "" then --in case of zombie windows
                repeat with t in tabs of w
                    set tabURL to URL of t
                    set the end of tabURLs to tabURL

                end repeat
            end if
        end repeat
        return tabURLs
    end tell
end takeSafariTabURLs

very helpful, you saved my time. thank you! commenting from FF, searched in Safari :D — Itzdsp, Feb 10 '19 at 01:00
Life saver!! Also ram saver (with help of AutoTabDiscard).. just saved 38 GB of RAM \o/ — Born2Smile, Mar 10 '20 at 01:20

score 2 · Answer 2 · answered Dec 01 '15 at 13:45

2

I tried following what Ramhound has mentioned, and it turned out to be very helpful. I saved all the bookmarks in a folder in Safari, and then imported the bookmarks in Firefox. It was just a simple process.

answered Dec 01 '15 at 13:45

Shubhankar Raj

121
3

Manny Tewolde · Answer 3 · 2020-01-26T01:50:16.327

Minor changes to preserve windows. I put a gist of this as well...if others want to improve it. see https://gist.github.com/amanuel/81e70673b057687e904a248218c50ce2

    tell application "Firefox"
    activate
    set safariWindows to getSafariWindows() of me
    repeat with w in safariWindows
        set newTabURLs to takeSafariTabURLs(w) of me
        repeat with tabURL in newTabURLs
            open location tabURL
            delay 0.5
        end repeat
        tell application "System Events" to keystroke "n" using command down
        delay 1
    end repeat
end tell

on getSafariWindows()
    set safariWindows to {}
    tell application "Safari"
        repeat with w in windows
            if name of w is not "" then --in case of zombie windows
                set the end of safariWindows to w
            end if
        end repeat
        return safariWindows
    end tell
end getSafariWindows

on takeSafariTabURLs(w)
    set tabURLs to {}
    tell application "Safari"
        repeat with t in tabs of w
            set tabURL to URL of t
            set the end of tabURLs to tabURL
        end repeat
        return tabURLs
    end tell
end takeSafariTabURLs

How to move all open tabs from Safari to Firefox?

3 Answers3